Parse RSS XML Feed in ASP

<%
' exact URL of the RSS XML file you are wanting to parse
RSSURL = "http://pressroom.prlog.org/ATSdiesel/rss.xml"

Dim objHTTP 'call object remotely
Dim RSSURL,RSSFeed 'set variables for RSS feed
Dim xmlRSSFeed 'set XML data into DOM object
Dim objItems,objItem, objChild 'temp variables to get various information
Dim title,description,link, pubdate 'variables that you are getting
Dim display 'This is the output variable

'convert raw XML to workable data
Set objHTTP = Server.CreateObject("Msxml2.ServerXMLHTTP")
objHTTP.open "GET",RSSURL,false
objHTTP.send
RSSFeed = objHTTP.responseText

'load raw XML data into an object
Set xmlRSSFeed = Server.CreateObject("MSXML2.DomDocument.4.0")
xmlRSSFeed.async = false
xmlRSSFeed.LoadXml(RSSFeed)

'clear objHTTP: No longer needed
Set objHTTP = Nothing

'This is where you get the information you are wanting
'When writing, I was using the following XML source:
'http://pressroom.prlog.org/ATSdiesel/rss.xml
' this code grabs all the "items" in the RSS Feed
Set objItems = xmlRSSFeed.getElementsByTagName("item")

'clear xmlRSSFeed: No longer needed
Set xmlRSSFeed = Nothing

' loop over all the items in the RSS Feed
For x = 0 to objItems.length - 1
' this code places the content from the various RSS nodes into local variables
Set objItem = objItems.item(x)
For Each objChild in objItem.childNodes
Select Case LCase(objChild.nodeName)
Case "title"
title = objChild.text
Case "link"
link = objChild.text
Case "description"
description = objChild.text
Case "pubdate" 'Note: pubDate in XML: Needs to be lowercase to work
pubDate = objChild.text
End Select
Next
'This is where the display for each occurence is constructed
display = display & "<a href=""" & link & """>" & title & "</a><br />" & pubDate & "<br />" & description & "<br /><br />"
Next
%>

<%=display%>

CDO SendMail Script

<%
email = "email@mydomain.com"
'check for email address...
if (email <> "") then 'need an email addy

Set Mail = Server.CreateObject("CDO.Message")

Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 'Send the message using the network (SMTP over the network).
Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.mydomain.com" 'SMTP link to your server
Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = ***Port ID*** 'SMTP Port
Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1 'Use SSL for the connection
Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'basic (clear-text) authentication
Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = "email@mydomain.com" 'email account actually sent from
Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password" 'password for email account from above

Mail.Configuration.Fields.Update

Mail.From = "email@mydomain.com" 'email you want it to be sent from

Mail.To = "recipient@theirdomain.com" 'email you want it sent to

Mail.HTMLBody = "Body Content Goes Here" 'content ofemail

Mail.Subject = "Subject" 'subject of email

On Error Resume Next
Mail.Send

if Err <> 0 Then
Response.Write "<font color=red size=+1>An error occurred while sending the email....</font>"
response.write(Err.Description)
else
response.write("Thank you.") 'Thank you for sending email
end if 'error
else
response.write("No Email submitted. Please try again") 'Need email to send to to process
end if 'need an email

%>